chore(nixos): rename nix configuration directory to nix-config

nixos/nix-config/modules/home-manager/users/user.nix

@@ -0,0 +1,21 @@
+{ self, withSystem, inputs, ... }:
+
+{
+  flake.homeConfigurations.user =
+    withSystem "x86_64-linux" ({ pkgs, ... }:
+      inputs.home-manager.lib.homeManagerConfiguration {
+        inherit pkgs;
+
+        modules = with self.homeModules; [
+          bash
+          cursor
+          kitty
+
+          {
+            home.username = "user";
+            home.homeDirectory = "/home/user";
+            home.stateVersion = "26.05";
+          }
+        ];
+      });
+}

nixos/nix-config/modules/nixos/features/niri.nix

@@ -0,0 +1,31 @@
+{ self, inputs, ... }: {
+  flake.nixosModules.niri = { pkgs, lib, ... }: {
+    programs.niri = {
+      enable = true;
+      package = self.packages.${pkgs.stdenv.hostPlatform.system}.myNiri;
+    };
+  };
+
+  perSystem = { pkgs, lib, self', ... }: {
+    packages.myNiri = inputs.wrapper-modules.wrappers.niri.wrap {
+      inherit pkgs;
+      settings = {
+        spawn-at-startup = [
+          (lib.getExe self'.packages.myNoctalia)
+        ];
+
+        xwayland-satellite.path = lib.getExe pkgs.xwayland-satellite;
+
+        input.keyboard.xkb.layout = "us,ru";
+
+        layout.gaps = 5;
+
+        # binds = {
+        #   "Mod+Return".spawn-sh = lib.getExe pkgs.kitty;
+        #   "Mod+Q".close-window = {};
+        #   "Mod+S".spawn-sh = "${lib.getExe self'.packages.myNoctalia} ipc call launcher toggle";
+        # };
+      };
+    };
+  };
+}

nixos/nix-config/modules/nixos/features/noctalia.nix

@@ -0,0 +1,10 @@
+{ self, inputs, ... }: {
+  perSystem = { pkgs, ... }: {
+    packages.myNoctalia = inputs.wrapper-modules.wrappers.noctalia-shell.wrap {
+      inherit pkgs;
+      # settings =
+      #   (builtins.fromJSON
+      #     (builtins.readFile ./noctalia.json)).settings;
+    };
+  };
+}

nixos/nix-config/modules/nixos/features/sddm.nix

@@ -0,0 +1,42 @@
+{ ... }: {
+  flake.nixosModules.sddm = { pkgs, ... }:
+
+    let
+      sddm-astrounaut = pkgs.sddm-astronaut.override {
+        embeddedTheme = "astronaut";
+
+	# astronaut
+        # black_hole
+        # cyberpunk
+        # hyprland_kath
+        # jake_the_dog
+        # japanese_aesthetic
+        # japanese_aesthetic
+        # pixel_sakura
+        # pixel_sakura_static
+        # post-apocalyptic_hacker
+        # purple_leaves
+
+      };
+  in {
+
+    environment.systemPackages = with pkgs; [
+      sddm-astrounaut 
+    ];
+
+    services.displayManager.sddm = {
+      enable = true;
+
+      package = pkgs.kdePackages.sddm;
+
+      theme = "sddm-astronaut-theme";
+
+      extraPackages = with pkgs; [ 
+        kdePackages.qtmultimedia
+      ];
+    };
+
+    services.xserver.enable = true;
+    
+  };
+}

nixos/nix-config/modules/nixos/hosts/laptop/configuration.nix

@@ -0,0 +1,48 @@
+{ self, inputs, ... }:
+
+let
+  machine = builtins.baseNameOf ./.;
+in
+{
+  flake.nixosModules."${machine}Configuration" = { pkgs, lib, ... }: {
+    imports = [
+      self.nixosModules."${machine}Hardware"
+      self.nixosModules.ssh
+      self.nixosModules.niri
+      self.nixosModules.sddm
+    ];
+
+    nix.settings.experimental-features = [
+      "nix-command"
+      "flakes"
+    ];
+
+    environment.systemPackages = with pkgs; [
+      git
+      vim
+      wget
+      curl
+      neovim
+      firefox
+      tree
+      inputs.home-manager.packages.${pkgs.system}.default
+    ];
+
+    boot = {
+      loader = {
+        systemd-boot.enable = true;
+        efi.canTouchEfiVariables = true;
+      };
+    };
+  
+    networking.hostName = "nixos-macbook-air-2017"; 
+    networking.networkmanager.enable = true;
+
+    users.users.user = {
+      isNormalUser = true;
+      extraGroups = [ "wheel" "input" "networkmanager" ]; 
+    };
+  
+    system.stateVersion = "26.05";  
+  };
+}

nixos/nix-config/modules/nixos/hosts/laptop/default.nix

@@ -0,0 +1,12 @@
+{ self, inputs, ... }:
+
+let
+  machine = builtins.baseNameOf ./.;
+in
+{
+  flake.nixosConfigurations.${machine} = inputs.nixpkgs.lib.nixosSystem {
+    modules = [
+      self.nixosModules."${machine}Configuration"
+    ];
+  };
+}

nixos/nix-config/modules/nixos/hosts/laptop/hardware.nix

@@ -0,0 +1,59 @@
+{ ... }:
+
+let
+  machine = builtins.baseNameOf ./.;
+in
+{
+  flake.nixosModules."${machine}Hardware" = { config, lib, modulesPath, ... }: {
+    imports = [
+      (modulesPath + "/installer/scan/not-detected.nix")
+    ];
+
+    boot = {
+      initrd = {
+        availableKernelModules = [
+          "xhci_pci"
+          "ahci"
+          "usbhid"
+          "usb_storage"
+          "sd_mod"
+        ];
+
+        kernelModules = [ ];
+      };
+
+      kernelModules = [
+        "kvm-intel"
+      ];
+
+      extraModulePackages = [ ];
+    };
+
+    fileSystems = {
+      "/" = {
+        device = "/dev/disk/by-uuid/992b8f95-6ca7-475d-b3ab-54c4339619e6";
+        fsType = "ext4";
+      };
+
+      "/boot" = {
+        device = "/dev/disk/by-uuid/A1EC-32E5";
+        fsType = "vfat";
+        options = [
+          "fmask=0022"
+          "dmask=0022"
+        ];
+      };
+    };
+
+    swapDevices = [
+      {
+        device = "/dev/disk/by-uuid/bfb36fe8-16b4-4ea5-a8dd-0f90b5dde2fb";
+      }
+    ];
+
+    nixpkgs.hostPlatform = lib.mkDefault "x86_64-linux";
+
+    hardware.cpu.intel.updateMicrocode =
+      lib.mkDefault config.hardware.enableRedistributableFirmware;
+  };
+}

nixos/nix-config/modules/nixos/services/ssh.nix

@@ -0,0 +1,14 @@
+{ ... }:
+
+{
+  flake.nixosModules.ssh = { ... }: {
+    services.openssh = {
+      enable = true;
+
+      settings = {
+        PasswordAuthentication = false;
+        PermitRootLogin = "no";
+      };
+    };
+  };
+}